// t1swdemon
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.

begincreaturescript;

variables;

short i,target,shaftnum,last_abil_time;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);

	message_dialog("The Shareware Demon disintegrates, letting out a final roar.","");
	put_boom_on_char(ME,0,0);
	erase_char(ME);
	run_animation_sound(119);
	pause(5);
	message_dialog("_Very well, mortal. I see my power over you is no more. Go now! Enjoy your life of adventures._ The discarnate demon scoffs and falls silent.","");
	award_char_xp(who_hit_me(),150,1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (tick_difference(last_abil_time,get_current_tick()) >= 1){
		shaftnum = get_ran(1,1,3);
		while (shaftnum > 0){
			text_bubble_on_char(ME,"SHAREWARE FEE!");
			force_instant_terrain_redraw();
			if (coins_amount() >= 25){
				put_effect_on_char(get_target(),10,3,1);
				run_animation_sound(15);
				change_coins(-25);
				print_str_color("Shareware fee of 25 coins!",4);
				shaftnum = shaftnum - 1;
			}
			else{
				print_str_color("Not enough money left...",4);
				put_effect_on_char(get_target(),12,3,1);
				run_animation_sound(65);
				damage_char(get_target(),get_ran(1,1,3),3);
				shaftnum = shaftnum - 1;
			}
		}
		last_abil_time = get_current_tick();
	}
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;